Les deux fonctions ET et OU imbriquées dans la fonction SI

L’article présent de la formation Excel vous montre comment imbriquer la fonction ET ou la fonction OU dans la fonction SI.

Les deux fonctions ET et OU imbriquées dans la fonction SI


Les deux fonctions Et et OU font partie de la catégorie des fonctions logiques d’Excel. Leur fonction est de tester plusieurs conditions pour renvoyer des valeurs logiques VRAI ou FAUX.

Cependant l’utilité de ces deux fonctions s’avèrent très importante lorsque vous les imbriquez dans une autre fonction telle que la fonction SI.

Essayons tout d’abord de voir comment peut-on utiliser les deux fonctions Et et OU, puis découvrons comment les imbriquer dans la fonction SI.

La fonction ET

La fonction ET renvoie VRAI si tous les arguments sont VRAI et renvoie FAUX si au moins l'un des arguments est FAUX.
  • Sa syntaxe est la suivante :

ET(valeur_logique1;[valeur_logique2];...)

Les arguments valeur_logique(1,2,3…) représentent les conditions à tester. On peut tester jusqu’à 255 conditions.

Exemple d’utilisation

Dans le tableau suivant, on veut donner une remise sur l’achat des Housses mais à condition que le smartphone acheté soit iPhone.

Tableau d'achat de smartphones


  • Commençons par tester en premier les valeurs contenues dans les deux cellules A2 et B2 si elles répondent à notre condition ou non.
  • Dans la cellule F2 entrez la formule suivante =ET(A2="iphone";B2="housse")
  • Le résultat renvoyé est VRAI.


Exemple d'utilisation de la fonction ET


  • Faites copier-coller dans les autres cellules en bas.
  • Voici ce que vous allez obtenir


deuxième exemple d'utilisation de la fonction ET


La fonction OU

La fonction OU renvoie la valeur VRAI si une des conditions testées est VRAI et la valeur FAUX si toutes les conditions sont fausses.
  • Sa syntaxe prend la forme suivante :

OU(valeur_logique1;[valeur_logique2],...)

Comme la fonction ET, la fonction OU peut tester jusqu’à 255 conditions.

Exemple d’utilisation :

  • En travaillant sur l’exemple précédent, on va maintenant offrir une remise sur l’achat des accessoires SAMSUNG ou si la quantité d’achat dépasse 150 quelque soit le smartphone acheté.
  • Pour cela, sélectionnez la cellule F2 et entrez la formule suivante : =OU(A2="Samsung";C2>150)


Exemple d'utilisation de la fonction OU


  • Excel affiche FAUX car aucune condition n’est remplie.
  • Faites copier-coller de la formule dans les autres cellules en bas, et voici le résultat que vous obtiendrez :


Deuxième exemple d'utilisation de la fonction OU


Imbriquer Et dans la fonction SI

Voilà maintenant on va imbriquer dans la fonction SI notre formule précédente dans laquelle nous avons utilisé la fonction ET pour calculer la remise de 10% sur l’achat des housses du smartphone iPhone.
Rappelons-nous cette formule qui s’est écrite de la façon suivante : =ET(A2="iphone";B2="housse")

En l’imbriquant dans la fonction SI, nous aurons la formule qui suit :
=SI(ET(A2="iphone";B2="housse");D2*10%;0)

Alors, si la fonction ET renvoie VRAI la remise sera calculée en multipliant le prix d’achat par 10%, et si la fonction ET renvoie Faux, un zéro 0 sera affiché.

  • Tapez cette formule dans la cellule E2, et voici ce que vous aurez comme résultat :

Imbriquer la fonction ET dans la fonction SI



  • Copiez ensuite la formule dans les autres cellules et remarquez le résultat obtenu :

Associer la fonction ET à la fonction SI - exemple 2


Imbriquer OU dans la fonction SI

De la même façon, on va imbriquer la fonction OU dans la fonction SI en repartons de notre exemple d’utilisation de la fonction OU vu en haut.

On va donc calculer une remise de 15% sur l’achat des accessoires SAMSUNG ou si la quantité d’achat dépasse 150 quelque soit le smartphone acheté.

Notre formule utilisant la fonction OU était : =OU(A2="Samsung";C2>150).

  • Sélectionnez alors la cellule E2 et entrez la formule suivante en imbriquant la fonction OU dans  la fonction SI :
=SI(OU(A2="Samsung";C2>150);D2*15%;0)

Imbriquer la fonction OU dans la fonction SI



  • Copiez ensuite la formule dans les cellules de E3 à E13
Note : vous pouvez aussi sélectionner la plage de cellules E2:E13, puis entrer la formule =SI(OU(A2="Samsung";C2>150);D2*15%;0) dans la barre de formule et taper enfin Ctrl+Entrée.

Insérer rapidement une formule dans plusieurs cellules


  • Voici alors le résultat affiché :

Associer la fonction OU à la fonction SI - exemple 2

Si imbriqué : 3 méthodes pour une bonne utilisation

On va parler dans cet article, de la formation Excel, de l’utilisation de SI imbriqué en vous présentant 3 méthodes différentes.
Si imbriqué


Dans l’article précédent, nous avons vu comment utiliser la fonction SI mais en traitant uniquement une seule condition à tester.
Aujourd’hui nous allons voir comment utiliser la fonction SI en testant plusieurs conditions. On parle donc de Si imbriqué.

Si nous reprenons la syntaxe de la fonction SI déjà vue, elle s’écrit de la façon suivante :
Si(test_logique ;[valeur_si_vrai] ;[valeur_si_faux])

La fonction SI renvoie le premier résultat si la condition est remplie, si non elle renvoie le deuxième résultat. Or, et si cette condition n’est pas remplie et que la fonction SI nécessite encore de tester une autre condition pour qu’elle puisse renvoyer le résultat souhaité, la syntaxe prendra alors la forme suivante :
Si(test_logique ;[valeur_si_vrai] ; Si(test_logique ;[valeur_si_vrai] ;[valeur_si_faux]))

De la même façon aussi et si on aura besoin de tester une troisième condition si les deux premières conditions ne sont pas remplies, nous allons écrire la syntaxe de la formule comme suit :

Si(test_logique ;[valeur_si_vrai] ;Si(test_logique ;[valeur_si_vrai] ;Si(test_logique ;[valeur_si_vrai] ;[valeur_si_faux]))).

Comme vous le remarquez nous avons imbriqué deux fonctions SI dans la première fonction SI, c’est pourquoi qu’on dit qu’on utilise une fonction SI imbriquée.

L’exemple suivant va éclaircir mieux les choses :

Tableau de chiffre d'affaire


Notre objectif est de calculer une prime selon les trois conditions suivantes :
  • Si le chiffre d’affaire est supérieur ou égal à 20000 euros, la prime sera égale à 3% de ce chiffre d’affaire.
  • Si le chiffre d’affaire est entre 10000 euros et 20000 euros non inclus, on calcule la prime en multipliant ce chiffre d’affaire par 2%.
  • Si le chiffre d’affaire est strictement inférieur à 10000 euros, aucune prime ne sera calculée.

Notre formule sera donc la suivante :

=SI(A2>=20000;A2*3%;SI(A2>=10000;A2*2%;""))

Insertion de la fonction SI imbriquée


Si donc la première condition est remplie, c’est-à-dire, si le chiffre d’affaire contenu dans la cellule A2 est supérieur ou égal (>=) à 20000 euros, la fonction SI applique le premier argument A2*3%.
Si cette condition n’est pas remplie, c’est-à-dire si le chiffre d’affaire est strictement inférieur à 20000 euros, on passe alors à la deuxième SI imbriquée qui va à son tour tester la deuxième condition définie dans son test logique : A2>=10000.
Si cette dernière est remplie donc la fonction SI calcule la prime en effectuant le calcul A2*2% ce qui donnera 300 euros dans ce cas, si non la fonction SI n’affiche rien car les deux premières conditions ne sont pas remplies.
  • Voici alors le résultat obtenu :


Résultat d'utilisation de la fonction SI imbriquée


  • En faisant une copie sur les cellules restantes, on obtient cet affichage :
Résultat total de SI imbriquée



Combien de fonctions SI peut-on imbriquer ?

Avec les versions récentes d’Excel, vous pouvez imbriquer un nombre maximum de 64 fonctions SI !!! c’est un nombre très intéressant mais aussi très difficile à gérer.

En effet, utiliser plusieurs fonctions SI imbriquées demande plus de précision et d’attention afin de ne pas commettre d’erreur. En plus, et pour que ces fonctions renvoient le bon résultat vous devez vous assurer que vous avez entré vos conditions dans un ordre correct, ce qui est très pénible surtout avec un grand nombre de fonctions SI utilisées.

Gardez le bon ordre des conditions

C’est un élément essentiel dans l’utilisation des fonctions SI imbriquées. Un ordre incorrect des conditions utilisées dans les arguments de ces fonctions mène à commettre des erreurs et à renvoyer des résultats illogiques.

Reprenons l’exemple en haut, et remarquez ce qui va se passer lorsqu’on changera l’ordre des conditions déterminées dans les fonctions SI utilisées :

Voici donc la formule qu’on a tapé en changeant l’ordre des conditions pour calculer la prime selon le chiffre d’affaire réalisé :

=SI(A2>=10000;A2*2%;SI(A2>=20000;A2*3%;""))

Ordre incorrect des conditions dans SI imbriquée


Vous voyez donc que la prime n’est pas bien calculée pour les chiffres d’affaires supérieurs à 20000 euros.
En effet, la fonction SI commence par tester la première condition A2>=10000, (en allant bien sûr de gauche à droite), si elle est remplie, la fonction SI applique ce qui est demandé dans le premier argument : « faire le calcul A2*2% », ce calcul donc sera effectué pour tous les chiffres d’affaires qui sont supérieurs à 10000 euros en incluant évidemment ceux qui sont supérieurs aussi à 20000 euros.

C’est pour cela qu’il est impérativement conseillé d’entrer les conditions dans un ordre correct.

Utiliser la fonction SI.CONDITIONS

Si vous disposez de la version Excel 2016 ou vous travaillez sur Excel Online, vous pouvez utiliser la fonction SI.CONDITIONS (IFS en anglais) qui permet d’utiliser plusieurs instructions SI imbriquées facilement.

La syntaxe de la fonction SI.CONDITIONS est de la forme suivante :

SI.CONDITIONS(test_logique1 ; valeur_si_Vrai1; [test_logique2 ; valeur_si_Vrai2];...[ test_logique127 ; valeur_si_Vrai127])

A partir de cette syntaxe, vous pouvez remarquer que la fonction SI.CONDITIONS a tout organisé pour vous, vous n’aurez pas besoin d’entrer de multiples SI ou de parenthèses, remplissez seulement les paramètres demandés selon l’ordre défini :
  • test_logique1 : cet argument vous permet d’entrer votre première condition. C’est obligatoire!
  • valeur_si_Vrai1 : entrez votre valeur que va renvoyer la fonction SI.CONDITIONS lorsque la première condition est remplie. C’est obligatoire aussi.
  • test_logique2 : cet argument vous permet d’entrer la deuxième condition qui sera testée lorsque la première n’est pas remplie. Ce choix est optionnelle.
  • valeur_si_Vrai2 : saisissez la valeur vraie correspondante à la deuxième condition.
  • Et ainsi de suite en gardant l’ordre : chaque condition est suivie de sa valeur vraie. Et comme vous l’avez vu sans doute, vous pouvez entrer jusqu’à 127 conditions différentes à tester.

Exemple pratique

Le tableau suivant présente des quantités différentes de stock :

tableau Quantité de stock


Nous souhaitons donc créer une formule qui répond à ces instructions de vérification de stock :
  • Si la quantité de stock est inférieure ou égale (<=) à 40, afficher le message « Stock épuisé ».
  • Si la quantité est entre 41 et 50 (inclus), afficher le message « Stock bientôt épuisé »
  • Si la quantité est entre 51 et 60 (inclus), afficher « Vérifiez votre stock ».
  • Si la quantité est supérieure à (>) 61, ne rien afficher.

Dans la cellule B2 entrez la formule suivante pour tester la quantité contenue dans la cellule A2 :

=SI.CONDITIONS(A2<=40;"Stock épuisé";A2<=50;"Stock bientôt épuisé";A2<=60;"Vérifiez votre stock";VRAI;"")

Copiez-la ensuite dans le reste des cellules, et voici ce que vous allez obtenir :

Exemple d'utilisation de la fonction SI.CONDITIONS


Note : 
  • Entrez la valeur VRAI pour spécifier un résultat par défaut lorsque toutes les conditions mentionnées ne sont pas remplies. Dans notre cas, VRAI remplace la condition A2>60.
  • Vous pouvez aussi entrer une formule qui renvoie toujours VRAI à la place de la valeur VRAI, par exemple 1=1, 200=200 ou 50=50 …
  • Veuillez aussi garder le bon ordre des conditions, et qu’elles renvoient uniquement les valeurs VRAI ou FAUX si non la fonction SI.CONDITIONS renvoie des erreurs.

Optez aussi pour la fonction SI.MULTIPLE

C’est une nouvelle fonction logique qui est apparue aussi avec l’arrivée de la version Excel 2016 et disponible également pour les utilisateurs d’Excel Online, la fonction SI.MULTIPLE (SWITCH en anglais) simplifie l’utilisation des instructions Si imbriquées mais d’une façon différente.
  • Voici la syntaxe de la fonction SI.MULTIPLE :

=SI.MULTIPLE(expression ;valeur1 ;résultat1 ;[défaut_ou_valeur2 ;résultat2]….;[défaut_ou_valeur126 ;résultat126])

Le travail de la fonction SI.MULTIPLE consiste à évaluer une valeur, entrée dans le paramètre expression, par rapport à une liste de valeurs (valeur1, valeur2 ……valeur126) et renvoie le résultat en fonction de la première valeur correspondante. S’il n’y a pas de correspondance, une valeur (facultative ) par défaut peut être renvoyée.

Suivez l’exemple suivant pour mieux comprendre l’utilisation de cette fonction :

  • Un dossier traité par une agence et avant d’être payé ou rejeté passe par les étapes suivantes :  Enregistré, en cours de traitement, validé ou non.

Chaque étape de traitement est spécifiée par un code comme c’est décrit dans la liste suivante accompagné de sa désignation:
  • PA : Payé
  • EN : Enregistré
  • EC : En cours de traitement.
  • VA : Validé
  • RE : Rejeté

Alors dans la cellule C2, nous entrons la formule suivante pour que la fonction SI.MULTIPLE renvoie la désignation du code contenu dans la cellule B2 qui sera donc la valeur à évaluer:

=SI.MULTIPLE(B2;"VA";"Validé";"EC";"En cours de traitement";"EN";"Enregistré";"PA";"Payé";"Rejeté")

Ensuite nous la copions dans les autres cellules de C3 à C10, et voici le résultat obtenu :

Exemple d'utilisation de la fonction SI.MULTIPLES



Note : la valeur par défaut dans cet exemple et qui sera affichée lorsqu’il n’y a aucune correspondance, est « Rejeté », et nous l’avons écrite en dernier. 

La fonction SI: 7 exemples pour bien l'utiliser et bien gérer ses paramètres

L’article présent de la formation Excel explique comment utiliser la fonction SI avec des textes, des nombres et des dates à travers des exemples vous présentant des solutions à des problèmes qui peuvent survenir lors de l’utilisation incorrecte des paramètres de cette fonction.
La fonction SI


La fonction SI est une fonction conditionnelle qui fait partie des fonctions logiques, et elle est l’une des fonctions les plus populaires d’Excel, elle permet de spécifier un test logique à effectuer.

Sa syntaxe prend la forme suivante :
Si(test_logique ;[valeur_si_vrai] ;[valeur_si_faux])

A partir de cette syntaxe vous pouvez déduire que la condition que vous spécifiez dans l’argument test_logique doit renvoyer soit la valeur VRAI soit la valeur FAUX.

Alors, si la condition est respectée c’est-à-dire qu’elle renvoie la valeur VRAI, la fonction SI applique ce que vous avez introduit dans le deuxième argument [valeur_si_vrai] ,si non, c’est-à-dire que la condition n’est pas respectée et qu’elle renvoie la valeur FAUX, la fonction SI applique alors ce que vous avez spécifié dans le troisième argument : [valeur_si_faux].

Un petit exemple :

Dans la cellule A1 nous avons tapé 2017.
Et dans la cellule A2 nous avons entré la formule suivante : =SI(A1=2017;"Année en cours";"Année différente")
Notre test logique est A1=2017. C’est-à-dire que la fonction SI doit vérifier si la cellule A1 contient 2017 ou non.
Dans notre cas A1 contient 2017, ce qui est VRAI. La fonction SI applique donc ce qui est défini dans le deuxième argument : Afficher « Année en cours » dans A2.

Fonction SI exemple



  • Remplaçons maintenant 2017 par 2018.
Notre test reste le même A1=2017, mais la condition n’est pas respectée cette fois : A1 ne contient pas 2017, notre test renvoie donc FAUX. Dans ce cas la fonction SI passe au troisième argument et applique ce qui est demandé : Afficher le texte « Année différente ».

Fonction SI exemple de valeur si faux


Note : Pour vérifier si notre condition renvoie une valeur logique (VRAI ou FAUX), nous pouvons faire un test en tapant dans la cellule B1 la formule suivante : =A1=2017

Tester une valeur vrai ou faux


Que pouvez-vous spécifier comme condition dans le premier argument test_logique ?

Que votre condition spécifiée traite du texte, des nombres, des dates ou utilise des opérateurs de comparaison, ou est sous forme de formules, l’essentiel est qu’elle doit renvoyer une valeur logique (VRAI ou FAUX).

Et quelle valeur renvoie la fonction SI après avoir testé la condition spécifiée ?

Comme nous l’avons montré précédemment, l’un des deux résultats que vous avez déterminé dans l’argument valeur_si_vrai ou l’argument valeur_si_faux sera renvoyé.

Ce résultat pourra être un texte, un nombre, une date, un calcul mathématique ou un résultat d’une formule effectuée.

Les deux arguments [valeur_si_vrai] et [valeur_si_faux] sont optionnels

En revenant à la syntaxe de la fonction SI, vous remarquez que les deux arguments valeur_si_vrai et valeur_si_faux sont écrits entre deux crochets, cela signifie dans Excel que ces arguments ne sont pas obligatoires et que vous pouvez les omettre.


  • Reprenons l’exemple précédent et entrez la formule suivante dans A2
=SI(A1=2017;)

  • Dans ce cas, la fonction SI vérifie la condition spécifiée et applique seulement le premier argument, et puisque nous avons laissé cet argument vide, Excel affiche ces valeurs par défaut :
Fonction SI sans arguments

    • Si renvoie 0 si la condition est respectée ; si non elle renvoie FAUX.
Mais si vous tapez deux points-virgules =SI(A1=2017 ;;), la fonction SI renvoie toujours 0.

Fonction Si renvoie toujours 0


En effet, la fonction SI renvoie par défaut 0 comme nous l’avons vu à l’instant si la condition est remplie (en appliquant le premier argument vide) , et lorsque la condition n’est pas remplie la fonction SI va appliquer cette fois le deuxième argument, et comme il est vide à son tour, la fonction SI renvoie par défaut la valeur 0 également.

Dans la plupart des cas, les deux arguments [valeur_si_vrai] et [valeur_si_faux] sont toujours définis par les utilisateurs, pour rendre mieux compréhensibles les résultats renvoyés par la fonction SI. Sauf dans le cas où vous aimeriez par exemple que la fonction SI ne renvoie rien, pour cela faites entrer les doubles guillemets ""  dans ces arguments.

Fonction SI renvoie le vide


Examinons maintenant de près ces exemples qui suivent pour mieux comprendre l’utilisation de la fonction SI :

Fonction SI traitant des conditions textuelles

Exemple 1 : Condition portant sur un texte exact

L’exemple suivant montre l’état de traitement des dossiers: Payé, ,enregistré, en cours de traitement ...

Exemple de tableau Excel


En utilisant la fonction SI nous aimons sélectionner uniquement les dossiers qui se sont payés.

  • Nous allons donc entrer la formule suivante dans la cellule C2 : =SI(B2="Payé";"Oui";"") et nous la copierons dans les cellules de C3 à C10.
Fonction SI vec texte exact


Remarquez donc que le mot « Payé » dans le test_logique est mis entre guillemets puisque c’est du texte.
Note : la fonction SI n’oblige pas de respecter la casse en entrant le mot « Payé ». si vous l’écrivez en minuscule (payé) ou en majuscule (PAYÉ), rien ne change.

Exemple 2 : Attention aux espaces avant et après le texte !!

Si nous reprenons l’exemple précédent et nous appliquons la même formule utilisée dans cet exemple, nous pouvons avoir un résultat non désiré.

Fonction Si problème espace avant le exte



  • Remarquez par exemple les deux cellules B8 et B10, elles contiennent le mot « Payé » mais la fonction SI renvoie du vide au lieu de la valeur « Oui ».
  • Le problème vient des espaces que nous avons tapés avant le mot "Payé" dans la cellule B8 et après le mot "Payé" dans la cellule B10.
Espaces avant et après textes Excel



  • Pour résoudre ce type de problème, nous utilisons la fonction SUPPRESPACE qui permet de supprimer les espaces du texte sauf bien sûr les espaces qui se trouvent entre les mots.
  • Voici donc la nouvelle formule à entrer dans la cellule C2: 
=SI(SUPPRESPACE(B2)="Payé";"Oui";"")


  • Copions la formule dans les autres cellules de C3 à C10, et voici ce que ça donne :
Fonction SI solution probleme espaces avant texte


Exemple 3 : Condition portant sur une partie du texte

Dans cet exemple, nous désirons afficher devant les cellules contenant « CLF » la réponse Oui, ou bien afficher Non dans le cas contraire.

  • Dans la cellule B2 nous allons entrer la formule suivante :
=SI(ESTNUM(CHERCHE("CLF";A2));"Oui";"Non")

Test logique portant sur une partie du texte dans la fonction SI


Comme vous pouvez le remarquer, nous avons imbriqué deux fonctions dans la fonction SI :

  • La fonction CHERCHE qui renvoie le numéro de position de la première lettre du mot recherché si ce dernier est trouvé, si non elle renvoie une valeur d’erreur #Valeur.
Utilisation de la fonction CHERCHE

  • La fonction ESTNUM vérifie si la valeur testée est numérique ou non. Elle va donc tester la valeur renvoyée par la fonction CHERCHE, si cette valeur est un nombre, ESTNUM renvoie VRAI, si cette valeur n’est pas un nombre, ESTNUM renvoie alors FAUX.
Utilisation de la fonction ESTNUM


Après ces deux étapes, intervient la fonction SI, qui va vérifier à son tour si la valeur renvoyée enfin par la fonction ESTNUM est VRAI, dans ce cas elle affiche Oui, si non elle affiche Non.

Utiliser la fonction SI avec test logique portant sur des nombres

Exemple 1 : Calculer une prime si

Dans l’exemple suivant, nous allons calculer une prime d’un chiffre d’affaire s’il est supérieur à 10000 euros en multipliant ce chiffre d’affaire par 3%.

  • La formule qui sera utilisée est la suivante :
=SI(A2>10000;A2*3%;0)

Remarquez que le montant 10000 est écris sans guillemets parce qu’il est de type numérique.

  • En copiant la formule dans les autres cellules, nous obtiendrons le résultat suivant :
Fonction SI supérieur à un nombre


Remarquez aussi que nous avons défini dans l’argument valeur_si_vrai une formule A2*3% qui sera effectuée lorsque la condition sera remplie.

Exemple 2 : Attention ! Quantité de stock épuisée !

Dans cet exemple, nous voulons afficher un message lorsque la quantité de stock est inférieure à 50.

  • Pour cela, nous utilisons la fonction SI de la façon suivante :
=SI(A2<50;"Epuisée";"")

  • La cellule A2 contient une quantité supérieure à 50, la cellule B2 n’affiche rien donc. Et en copiant la formule dans les autres cellules nous aurons ce résultat :
Fonction SI inférieur à une valeur numérique


Fonction SI avec test logique portant sur des dates

Exemple 1 : comparaison de deux dates

Le tableau suivant comporte une liste des dates de rendez-vous différentes. Nous estimons savoir si la date d’un rendez-vous pris est écoulée ou pas encore.

  • Pour cela nous avons entré la formule suivante dans la première cellule B2 :
=SI(A2<"24/04/2017";"Date écoulée";"Date future")

  • Puis nous l’avons copiée dans les cellules qui restent.
Fonction SI problème date



  • Mais le problème c’est que notre formule nous renvoie Date écoulée même si la date du rendez-vous est inférieure à la date d’aujourd’hui (24/04/2017)
  • La cause de ce problème est que la fonction SI ne traite pas les dates contenues dans ses paramètres et écrites comme ça  « 24/04/2017 » ou comme ça 24/04/2017 comme des valeurs de type date. Elle les considère comme des chaines de texte.
  • Pour dépasser donc ce problème, vous devez convertir votre date saisie en numéro de série reconnu par Excel comme une date.
  • Par exemple le numéro de série de la date écrite sous forme de 24/04/2017 est 42849.
1) Alors, notre formule pourra s’écrire comme ça :
=SI(A2<42849;"Date écoulée";"Date future")
Voici le résultat après avoir copié la formule :

Fonction SI avec date sous forme de numéro de série


2) Nous pouvons aussi taper la date dans une autre cellule et utiliser sa référence absolue dans notre formule :
=SI(A2<$D$2;"Date écoulée";"Date future")

Fonction SI utilisant date contenue dans une cellule


Note : lorsque vous écrivez une date dans une cellule, Excel la stocke sous la forme d’un numéro de série séquentiel afin qu’elle soit utilisable dans des calculs.

3) Ou bien utiliser la fonction DATEVAL qui permet de convertir la date écrite dans le test logique en numéro de série.
Voici notre formule obtenue :
=SI(A2<DATEVAL("24/04/2017");"Date écoulée";"Date future")

Et voici le résultat donc :

Fonction SI et DATEVAL


Note : Vous devez écrire votre date entre des guillemets, si non la fonction DATEVAL renvoie une erreur de type #VALEUR !

Exemple 2 : utiliser un calcul de date dans le test logique

Par exemple, une agence a l’habitude de rappeler ses clients de leurs rendez-vous et ceci 10 jours avant la date fixée.

  • Pour cela nous allons utiliser la fonction SI pour nous renvoyer un message texte par exemple « Rappelez » lorsqu’il reste 10 jours ou moins à la date du rendez-vous.
  • Dans la cellule B2, nous allons donc taper la formule suivante :
=SI(A2-AUJOURDHUI()<=10;"Rappelez";"")

  • Nous copions ensuite la formule et voici le résultat obtenu:
Fonction SI avec fonction AUJOURDHUI


Vous pouvez améliorer la formule pour que la fonction SI affiche un message vous informant précisément du nombre de jours restés.
=SI(A2-AUJOURDHUI()<=10;"Il vous reste " &A2-AUJOURDHUI()&" jours";"")

Fonction SI calculer nombre de jours

8 cas qui expliquent comment utiliser la fonction NB.SI.ENS

L’article présent de la formation Excel vous fait découvrir comment utiliser la fonction NB.SI.ENS pour appliquer plusieurs critères aux plages de cellules. Les critères qui seront traités dans les 8 exemples d’utilisation de NB.SI.ENS qui suivent, sont de types texte, numérique, date … Cet article va vous montrer aussi comment compter le nombre de cellules non vides correctement, et comment utiliser NB.SI.ENS avec OU logique.

La fonction NB.SI.ENS


La fonction NB.SI.ENS vous permet de compter le nombre de cellules répondant à plusieurs critères de types différents : Nombre, Texte, Date, valeur logique….
La syntaxe de la fonction NB.SI.ENS est :
NB.SI.ENS(plage_critères1; critères1; [plage_critères2; critères2]…)

Les deux arguments plage_critères1 et critères1 sont obligatoires au fonctionnement de la fonction NB.SI.ENS, quant aux autres paires plages_critères/critères, elles sont facultatives.

Combien de paires plages-critères/critères pouvez-vous introduire dans la fonction NB.SI.ENS ?
  • La fonction NB.SI.ENS peut contenir jusqu’à 127 paires plages-critères/critères.

Note : la plage critères doit être insérée toujours avant le critère associé.

Pour bien comprendre comment utiliser la fonction NB.SI.ENS, veuillez suivre ces 8 exemples :
  • Partons de ce petit tableau et entamons le premier exemple :


Liste des ventes


Exemple 1 : Combien de vendeurs ont réalisé un montant de vente plus que 3000 Euros à Paris ?

  • Sélectionnez une cellule pour y insérer la formule suivante :

=NB.SI.ENS(C2:C14;"Paris";D2:D14;">3000")
Cette formule permet de sélectionner en premier les cellules contenant « Paris » dans la plage de cellules C2:C14, puis de trouver les montants supérieurs à 3000 Euros dans la plage de cellules D2:D14 et qui correspondent à ces cellules.

Fonction NB.SI.ENS


Note : pour le premier critère "Paris", il est écrit entre guillemets puisque c’est un texte. Et pour le deuxième critère ">3000", il est écrit aussi entre guillemets parce que le nombre 3000 est précédée d’un opérateur de comparaison ">".
Normalement lorsqu’un critère est de type numérique, on l’écrit sans guillemets, mais si vous lui faites accompagner <,>, = ou <> vous devez le mettre entre guillemets.

Exemple 2 : Utilisation des références de cellules dans les arguments de la fonction NB.SI.ENS

Dans cet exemple, nous avons écrit les critères Nom de ville dans la cellule F4, et le montant de vente dans F6.
Au lieu de modifier à chaque fois notre formule exemple de NB.SI.ENS, nous allons tout simplement changer les données dans ces deux cellules F4 et F6 :

  • Voici donc notre formule dynamique que nous allons utiliser :

=NB.SI.ENS(C2:C14;F4;D2:D14;">"&F6)

Utilisation de références de cellules dans NB.SI.ENS

  • Remarque n°1 : le critère nom de la ville est remplacé par la référence de cellule F4 sans guillemets.
  • Remarque n°2 : pour le critère >3000, nous avons laissé l’opérateur > entre guillemets et avons ajouté une esperluette suivie de la référence F6 sans guillemets.

Essayons maintenant de remplacer Paris par Lisbonne et remarquez que le résultat est mis à jour automatiquement :

fonction NB.SI.ENS dynamique


Note : ne mettez pas une référence de cellules entre guillemets lorsque vous l’utilisez comme critère de la fonction NB.SI.ENS.

Exemple 3 : Combiner des astérisques avec des références de cellules

Par exemple, si vous voulez compter le nombre de cellules contenant le nom Antoine qui travaille à Lisbonne, tapez la formule suivante :
=NB.SI.ENS(B2:B14;"*"&F6&"*";C2:C14;F4)

NB.SI.ENS avec critère astérisques


Vous voyez les deux esperluettes qui se sont placées avant et après la référence de cellule F6.

Exemple 3 : Compter le nombre de cellules contenant des montants entre 2000 et 4000 Euros

Dans cet exemple, vous allez traiter deux critères de type numériques et qui se trouvent dans la même colonne ou plage de cellules.
  • Commencez d’abord par donner à chaque colonne de votre tableau un nom significatif que vous allez utiliser comme référence dans les arguments de votre fonction NB.SI.ENS. ça va vous faciliter le travail !

Par exemple renommer la plage :
  • A2:A14 par Date_Vente
  • B2:B14 par Vendeurs
  • C2:C14 par Villes
  • D2:D14 par Montants.


Renomer une plage de cellules


  • Sélectionnez une cellule vide et tapez =NB.SI.ENS( puis tapez  mon  pour faire apparaître le nom de la colonne Montants.
  • Sélectionnez-le donc et continuez la saisie de votre formule pour obtenir la formule suivante :

=NB.SI.ENS(Montants;">2000";Montants;"<4000")

NB.SI.ENS avec critères numériques


Attention !
Il faut que les plages de critères utilisées dans la fonction NB.SI.ENS aient le même nombre de lignes, si non Excel retournera une erreur de type #VALEUR !.

Utilisation des critères de type date dans la fonction NB.SI.ENS

Exemple 4 : Compter le nombre de ventes réalisées entre le 05/04/2017 et le 08/04/2017

  • Sélectionnez une cellule vide et entrez la formule suivante :
=NB.SI.ENS(A2:A14;">=05/04/2017";A2:A14;"<=08/04/2017")
  • Faites attention aux guillemets !


NB.SI.ENS avec critères dates


Exemple 5: Compter le nombre de ventes réalisées à Londres entre le 05/04/2017 et aujourd’hui et ayant un montant supérieur à 2000 Euros

Notre formule va contenir donc trois plages de critères : Date de vente, Ville et Montant de vente et la fonction AUJOURDHUI() :
  • Sélectionnez une cellule vide et entrez la formule suivante :

=NB.SI.ENS(Date_Vente;">=05/04/2017";Date_Vente;"<="&AUJOURDHUI();Ville;C14;Montants;">2000")

NB.SI.ENS avec 4 critères


  • L’objectif de cet exemple est de vous présenter une fonction NB.SI.ENS contenant quatre critères.

NB.SI.ENS différent de

Exemple 6 : Compter le nombre de cellules contenant toutes les noms de villes sauf  "Paris" et dont la date de vente est postérieure ou égale à 05/04/2017

  • Entrez la formule suivante en introduisant l’opérateur <> :

=NB.SI.ENS(Ville;"<>paris";Date_Vente;">=05/04/2017")

NB.SI.ENS différent de texte


Exemple 7 : Compter le nomber des cellules non vides

Vous avez vu dans l’article: "NB, NBVAL et NBVIDE comptent le nombre de cellules différemment" comment compter le nombre de cellules non vides en utilisant la fonction NBVAL. Et pour le faire avec la fonction NB.SI.ENS, tapez la formule suivante qui va vous permettre de compter le nombre de montants de ventes réalisées à Londres en ignorant les montants non encore enregistrés :
  • Par exemple la cellule D14 est vide.

=NB.SI.ENS(Ville;"Londres";Montants;"<>"&"")

NB.SI.ENS différent de vide


  • Remarquez donc que le critère vide est exprimé par les deux guillemets ""
  • Remarquez aussi que nous avons mis une esperluette & entre l’opérateur <> et le critère vide pour que la fonction renvoie le bon résultat.

NB.SI.ENS avec OU

Vous avez sans doute constaté que tous les critères utilisés dans la fonction NB.SI.ENS sont évalués dans les exemples précédents, alors que parfois vous souhaitez que NB.SI.ENS soit effectuée en répondant à un seul caractère au moins,  tout comme l’utilisation d’un OU logique.

Pour utiliser donc la fonction NB.SI.ENS avec OU, la solution consiste à faire l’addition des fonctions NB.SI.ENS associée chacune à son critère.

Exemple 8 : Compter le nombre de cellules contenant Paris et Londres dont les montants réalisés sont supérieurs à 3000 Euros.

  • Sélectionnez une cellule vide et entrez la formule suivante :

=NB.SI.ENS(Ville;"Paris";Montants;">2000")+NB.SI.ENS(Ville;"Londres";Montants;">2000")

NB.SI.ENS avec OU


Dans cet exemple nous avons utilisé une fonction NB.SI.ENS avec le critère Paris et une autre avec le critère Londres, et les deux contiennent aussi le même critère >2000

Pour vous assurer bien de la fonctionnalité de cette formule, faites un filtre des données comme s’est illustré dans l’image animée suivante :

Filtrer des données selon deux critères avec OU logique


La fonction NB.SI.ENS et le VBA

Terminons cet article par une solution à un petit problème qui gêne beaucoup les utilisateurs de VBA Excel (surtout les novices !) lorsqu’ils veulent utiliser la fonction NB.SI.ENS dans leur code VBA.

L’erreur qu’ils commettent c’est qu’ils utilisent la nomination en français de la fonction NB.SI.ENS dans leurs codes et bien sûr ces codes ne fonctionneront pas bien.
C’est tout à fait normal car dans VBA, ils doivent taper la fonction NB.SI.ENS en anglais comme ça : COUNTIFS.


NB.SI.ENS en anglais