Dans cet article, de la formation Excel, nous allons voir comment utiliser SI imbriqué en suivant 3 méthodes différentes.
Dans l’article précédent, nous
avons vu comment utiliser la fonction SI mais en traitant uniquement une seule
condition à tester.
Aujourd’hui nous allons voir comment utiliser la fonction SI en testant plusieurs conditions. On parle donc
de Si imbriqué.
Si nous reprenons la syntaxe de
la fonction SI déjà vue, elle s’écrit de la façon suivante :
Si(test_logique ;[valeur_si_vrai] ;[valeur_si_faux])
La fonction SI renvoie le premier
résultat si la condition est remplie, si non elle renvoie le deuxième résultat.
Or, et si cette condition n’est pas remplie et que la fonction SI nécessite
encore de tester une autre condition pour qu’elle puisse renvoyer le résultat
souhaité, la syntaxe prendra alors la forme suivante :
Si(test_logique ;[valeur_si_vrai] ;
Si(test_logique ;[valeur_si_vrai] ;[valeur_si_faux]))
De la même façon aussi et si on
aura besoin de tester une troisième condition si les deux premières conditions
ne sont pas remplies, nous allons écrire la syntaxe de la formule comme
suit :
Si(test_logique ;[valeur_si_vrai] ;Si(test_logique ;[valeur_si_vrai] ;Si(test_logique ;[valeur_si_vrai] ;[valeur_si_faux]))).
Comme vous le remarquez nous
avons imbriqué deux fonctions SI dans la première fonction SI, c’est pourquoi
qu’on dit qu’on utilise une fonction SI imbriquée.
L’exemple suivant va éclaircir
mieux les choses :
Notre objectif est de calculer
une prime selon les trois conditions suivantes :
- Si le chiffre d’affaire est supérieur ou égal à 20000 euros, la prime sera égale à 3% de ce chiffre d’affaire.
- Si le chiffre d’affaire est entre 10000 euros et 20000 euros non inclus, on calcule la prime en multipliant ce chiffre d’affaire par 2%.
- Si le chiffre d’affaire est strictement inférieur à 10000 euros, aucune prime ne sera calculée.
Notre formule sera donc la
suivante :
=SI(A2>=20000;A2*3%;SI(A2>=10000;A2*2%;""))
Alors, si la première condition est
remplie, c’est-à-dire, si le chiffre d’affaire contenu dans la cellule A2 est
supérieur ou égal (>=) à 20000 euros, la fonction SI applique le premier
argument A2*3%.
Si cette condition n’est pas
remplie, c’est-à-dire si le chiffre d’affaire est strictement inférieur à 20000
euros, on passe alors à la deuxième SI imbriquée qui va, à son tour, tester la
deuxième condition définie dans son test logique : A2>=10000.
Si cette dernière est remplie
donc la fonction SI calcule la prime en effectuant le calcul A2*2% ce qui
donnera 300 euros dans ce cas, si non la fonction SI n’affiche rien car les
deux premières conditions ne sont pas remplies.
- Voici alors le résultat obtenu :
- En faisant une copie sur les cellules restantes, on obtient cet affichage :
Combien de fonctions SI peut-on imbriquer ?
Avec les versions récentes d’Excel, vous pouvez imbriquer un nombre maximum de 64 fonctions SI !!!
c’est un nombre très intéressant mais aussi très difficile à gérer!
En effet, utiliser plusieurs
fonctions SI imbriquées demande plus de précision et d’attention afin de ne pas
commettre d’erreur. En plus, et pour que ces fonctions renvoient le bon
résultat vous devez vous assurer que vous avez entré vos conditions dans un
ordre correct, ce qui est très pénible surtout avec un grand nombre de
fonctions SI utilisées.
Gardez le bon ordre des conditions
C’est un élément essentiel dans
l’utilisation des fonctions SI
imbriquées. Un ordre incorrect des conditions utilisées dans les arguments de
ces fonctions mène à commettre des erreurs et à renvoyer des résultats illogiques.
Reprenons l’exemple en haut, et
remarquez ce qui va se passer lorsqu’on changera l’ordre des conditions
déterminées dans les fonctions SI utilisées :
Voici donc la formule qu’on a
tapé en changeant l’ordre des conditions pour calculer la prime selon le
chiffre d’affaire réalisé :
=SI(A2>=10000;A2*2%;SI(A2>=20000;A2*3%;""))
Vous voyez donc que la prime
n’est pas bien calculée pour les chiffres d’affaires supérieurs à 20000 euros.
En effet, la fonction SI commence
par tester la première condition A2>=10000, (en allant bien sûr de gauche à
droite), si elle est remplie, la fonction SI applique ce qui est demandé dans
le premier argument : « faire le calcul A2*2% », ce calcul donc
sera effectué pour tous les chiffres d’affaires qui sont supérieurs à 10000
euros en incluant évidemment ceux qui sont supérieurs aussi à 20000 euros.
C’est pour cela qu’il est
impérativement conseillé d’entrer les conditions dans un ordre correct.
Utiliser la fonction SI.CONDITIONS
Si vous disposez de la version Excel 2016 ou vous travaillez sur Excel Online, vous pouvez utiliser la
fonction SI.CONDITIONS (IFS en anglais) qui permet d’utiliser plusieurs
instructions SI imbriquées facilement.
La syntaxe de la fonction
SI.CONDITIONS est de la forme suivante :
SI.CONDITIONS(test_logique1 ;
valeur_si_Vrai1; [test_logique2 ; valeur_si_Vrai2];...[ test_logique127 ;
valeur_si_Vrai127])
A partir de cette syntaxe, vous
pouvez remarquer que la fonction SI.CONDITIONS a tout organisé pour vous, vous
n’aurez pas besoin d’entrer de multiples SI ou de parenthèses, remplissez
seulement les paramètres demandés selon l’ordre défini :
- test_logique1 : cet argument vous permet d’entrer votre première condition. C’est obligatoire!
- valeur_si_Vrai1 : entrez votre valeur que va renvoyer la fonction SI.CONDITIONS lorsque la première condition est remplie. C’est obligatoire aussi.
- test_logique2 : cet argument vous permet d’entrer la deuxième condition qui sera testée lorsque la première n’est pas remplie. Ce choix est optionnelle.
- valeur_si_Vrai2 : saisissez la valeur vraie correspondante à la deuxième condition.
- Et ainsi de suite en gardant l’ordre : chaque condition est suivie de sa valeur vraie. Et comme vous l’avez vu sans doute, vous pouvez entrer jusqu’à 127 conditions différentes à tester!
Exemple pratique
Le tableau suivant présente des quantités
différentes de stock :
Nous souhaitons donc créer une
formule qui répond à ces instructions de vérification de stock :
- Si la quantité de stock est inférieure ou égale (<=) à 40, afficher le message « Stock épuisé ».
- Si la quantité est entre 41 et 50 (inclus), afficher le message « Stock bientôt épuisé »
- Si la quantité est entre 51 et 60 (inclus), afficher « Vérifiez votre stock ».
- Si la quantité est supérieure à (>) 61, ne rien afficher.
Dans la cellule B2 entrez la
formule suivante pour tester la quantité contenue dans la cellule A2 :
=SI.CONDITIONS(A2<=40;"Stock
épuisé";A2<=50;"Stock bientôt
épuisé";A2<=60;"Vérifiez votre stock";VRAI;"")
Copiez-la ensuite dans le reste
des cellules, et voici ce que vous allez obtenir :
Note :
- Entrez la valeur VRAI pour spécifier un résultat par défaut lorsque toutes les conditions mentionnées ne sont pas remplies. Dans notre cas, VRAI remplace la condition A2>60.
- Vous pouvez aussi entrer une formule qui renvoie toujours VRAI à la place de la valeur VRAI, par exemple 1=1, 200=200 ou 50=50 …
- Veuillez aussi garder le bon ordre des conditions, et qu’elles renvoient uniquement les valeurs VRAI ou FAUX si non la fonction SI.CONDITIONS renvoie des erreurs.
Optez aussi pour la fonction SI.MULTIPLE
C’est une nouvelle fonction
logique qui est apparue aussi avec l’arrivée de la version Excel 2016 et
disponible également pour les utilisateurs d’Excel Online, la fonction SI.MULTIPLE
(SWITCH en anglais) simplifie l’utilisation des instructions Si imbriquées mais
d’une façon différente.
- Voici la syntaxe de la fonction SI.MULTIPLE :
=SI.MULTIPLE(expression ;valeur1 ;résultat1 ;[défaut_ou_valeur2 ;résultat2]….;[défaut_ou_valeur126 ;résultat126])
Le travail de la fonction SI.MULTIPLE consiste
à évaluer une valeur, entrée dans le paramètre expression, par rapport à une
liste de valeurs (valeur1, valeur2 ……valeur126) et renvoie le résultat en
fonction de la première valeur correspondante. S’il n’y a pas de
correspondance, une valeur (facultative ) par défaut peut être renvoyée.
Suivez l’exemple suivant pour
mieux comprendre l’utilisation de cette fonction :
- Un dossier traité par une agence et avant d’être payé ou rejeté passe par les étapes suivantes : Enregistré, en cours de traitement, validé ou non.
Chaque étape de traitement est spécifiée
par un code, comme c’est décrit dans la liste suivante, accompagné de sa
désignation:
- PA : Payé
- EN : Enregistré
- EC : En cours de traitement.
- VA : Validé
- RE : Rejeté
Alors dans la cellule C2, nous entrons
la formule suivante pour que la fonction SI.MULTIPLE renvoie la
désignation du code contenu dans la cellule B2 qui sera donc la valeur à
évaluer:
=SI.MULTIPLE(B2;"VA";"Validé";"EC";"En
cours de traitement";"EN";"Enregistré";"PA";"Payé";"Rejeté")
Ensuite nous la copions dans les autres
cellules de C3 à C10, et voici le résultat obtenu :
Note : la valeur par défaut
dans cet exemple et qui sera affichée lorsqu’il n’y a aucune correspondance, est
« Rejeté », et nous l’avons écrite en dernier.
A corriger car ça fait un peu mal aux yeux et oreilles.
RépondreSupprimerJe serai très content si vous enrichissiez
OU
Je SUIS très content si vous enrichissez
Cordialement
TRÈS INTERESSANT, BRAVO!!!
RépondreSupprimerJe vous en prie.
SupprimerMerci c'est beaucoup plus simple avec vos explications
RépondreSupprimerJe vous en prie.
SupprimerTrès clair et intéressant. Merci bien
RépondreSupprimerJe vous en prie.
SupprimerTrès belles explications et illustrations.
RépondreSupprimerMerci beaucoup
RépondreSupprimerJe vous en prie.
SupprimerMerci bien
RépondreSupprimerJe vous en prie.
Supprimermerci beaucoup, c'est très bien expliqué , mille fois merci et Bravo !
RépondreSupprimerJe vous en prie.
SupprimerTrès bien expliqué. Merci
RépondreSupprimerJe vous en prie.
Supprimer