Comment créer un tableau de comparaison des offres ?

Dans cet exercice je vais vous montrer comment établir un tableau de comparaison des offres, en se basant sur les réponses des fournisseurs à un appel d'offres lancé par un hôtel qui désire renouveler les chaises de ses 150 chambres.

Ce tableau de comparaison des offres va permettre à notre hôtel de sélectionner le fournisseur qui propose le prix le moins cher. Ce fournisseur doit aussi respecter le critère de livrer la commande dans un délai qui ne dépasse pas les 30 jours.

Tout d’abord, j’ai préparé ce fichier (que vous pouvez télécharger ici) dans lequel vous pouvez voir, en plus de mon tableau de comparaison des offres, une petite partie intitulée Besoins et critères concernant ce que demande l’hôtel.

Et dans le tableau qui se trouve en dessous et qui porte le nom de Réponses des fournisseurs, j'ai saisi les données collectées des réponses des fournisseurs reçues par l’hôtel. Ces données vont me servir à remplir mon tableau de comparaison des offres et d’en faire une étude comparative afin de sélectionner le fournisseur qui présente la meilleure offre pour mon hôtel.

Entamons le remplissage de notre tableau de comparaison des offres :

Pour le prix unitaire, vous pouvez soit copier les prix à partir du tableau Réponses des fournisseurs soit créer une petite formule qui va introduire ces valeurs d’une façon automatique.

Sélectionnez donc les trois cellules Prix unitaire puis tapez =G9, validez ensuite par Ctrl+Entrée.

Calculer le montant total HT :

Le montant total = le prix unitaire x le nombre de chaises

De la même manière et pour insérer cette formule dans les trois cellules du Montant Total HT, sélectionnez ces dernières puis saisissez =B6*$G$3, validez enfin par Crtl+Entrée.

Remarque : N’oubliez pas de figer la cellule G3 qui contient le nombre de chaises.

Insérer le taux de remise

Vous remarquez sans doute que dans le tableau des réponses des fournisseurs, le fournisseur F2 ne fournit aucune remise, alors que les deux autres proposent leurs remises mais suivant quelques conditions :

• Pour le fournisseur F1 :

La remise de 6%  est applicable à partir de 100 chaises commandées, ce que nous allons traduire sous forme d’une formule utilisant la fonction SI :

- Sélectionnez donc la cellule B8 puis tapez cette formule : =SI(G3>=G11;G10;"")

- G3 contient le nombre de chaises commandées et qui est supérieur à 100 déjà saisi dans G11.

- Dans ce cas, Excel va afficher alors 6% se trouvant dans la cellule G10.

• Pour le fournisseur F2 :

Il propose une remise qui varie en fonction du nombre de chaises commandées :

5% à partir de 80 chaises et 10% si la quantité passe à 100 chaises ou plus.

Voici la formule à insérer dans la cellule D8 :

=SI(G3>=I13;I12;SI(G3>=I11;I10;""))

J’explique :

Si le nombre de chaises contenu dans G3 est supérieur ou égal à 100 se trouvant dans I13, le taux 10% sera affiché, sinon, on demande à Excel de vérifier si cette quantité commandée est supérieure ou égale à 80 que contient I11 et d’afficher donc 5% se trouvant dans I10.

Si aucune condition n’est respectée, alors Excel n’affichera rien.

Le nombre de chaises dépasse 100, alors le taux 10% est affiché.

Calculer le montant de remise :

Le montant de remise = le montant total x le taux de remise

Sélectionnez les trois cellules B9, C9 et D9 puis tapez  =B7*B8 et validez par Ctrl+Entrée.

Note : appliquez le format monétaire ou comptabilité pour mettre en forme les montants calculés.

Calculer le Net commercial

C’est le montant total HT – le montant de remise

Sélectionnez la plage de cellules B10:D10 puis tapez ceci =B7-B9 et validez ensuite par Ctrl+Entrée.

Insérer le taux d’escompte

Copiez tout simplement les valeurs à partir du tableau des réponses des fournisseurs ou sélectionnez les trois cellules de B11 à D11 puis tapez =G14 et validez par Ctrl+Entrée.

Calculer le montant d’escompte

Il égale à : Net commercial x taux d’escompte

Pour faire rapidement comme d’habitudes, sélectionnez la plage de cellules B12:D12 puis saisissez la formule suivante : =B10*B11, validez ensuite par Ctrl+Entrée

Calculer le Net financier

le Net financier= Net commercial - montant d’escompte

Sélectionnez les cellules du Net financier puis insérez cette formule =B10-B12, validez ensuite par Ctrl+Entrée.

Saisir le frais de transport :

Le fournisseur F2 propose de livrer la marchandise gratuitement contrairement aux deux autres.

Copiez donc le frais correspondant au fournisseur F1, quant au fournisseur F3 vous avez besoin de calculer ce frais en fonction du pourcentage qu’il précise (1% du Net commercial).

Pour cela, sélectionnez la cellule D14 et saisissez la formule suivante : =D10*1%

Calculer le Net HT

le Net HT = le Net financier + frais de livraison

Sélectionnez donc les trois cellules qui vont afficher le Net HT puis saisissez la formule =SOMME(B13:B14), validez ensuite par Ctrl+Entrée.

Insérer les données du délai de livraison et de la garantie

Sélectionnez la plage de cellules B16:D17 et insérez cette petite formule =G16 puis validez par Ctrl+Entrée.

Si vous souhaitez afficher les nombres des jours suivis du mot "jours", procédez comme suit :

• Sélectionnez les cellules contenant ces nombres puis cliquez sur la flèche située dans le coin inférieur droit du groupe Nombre.
• Dans la fenêtre qui apparaît cliquez sur Personnalisée
• Dans la zone Type tapez 0" jours" et cliquez enfin sur le bouton OK.

Suivez la même démarche si vous souhaitez également afficher le mot « mois » devant le nombre de mois de la garantie.

Choisir le fournisseur approprié

Pour ce faire, nous allons analyser ces deux données essentielles : Net HT et Délai de livraison.

Pour notre hôtel, ce qui est favorable pour lui c’est :

• Le Net HT le moins élevé,
• Un délai de livraison le plus bref qui ne dépasse pas les 30 jours prédéfinis.

Comme vous pouvez le remarquez, bien entendu, et d’après les résultats obtenus, le fournisseur F1 la ramène parce que son offre est la moins chère (30 629,70 Euros) , en plus, il est le seul qui propose de livrer la commande dans un délai plus rapide  (15 jours ) par rapport aux autres fournisseurs.

Pour traduire ce travail sous Excel, vous pouvez procéder ainsi :

• Afficher le nom du fournisseur proposant le prix le plus petit :

Sélectionnez la cellule B19, puis tapez la formule suivante :

=SI(B15=MIN($B$15:$D$15);B5;"")

Premièrement Excel va vérifier si le montant Net HT du Fournisseur F1 égale au montant le plus petit de ceux obtenus, si c’est le cas ; il affiche le nom de ce fournisseur contenu dans la cellule B5, sinon Excel n’affichera rien.

Puis on copie la formule dans les deux cellules C19 et D19.

• Afficher le nom du fournisseur qui va livrer la commande rapidement :

Sélectionnez la cellule B20, et tapez la formule suivante :

=SI(ET(B16<=$G$4;B16=MIN($B$16:$D$16));B5;"")

Dans cette formule, nous avons deux conditions à vérifier :

Le délai de livraison ne doit pas dépasser les 30 jours (B16<=$G$4) et s'il est le plus petit parmi les trois proposés par nos fournisseurs (B16=MIN($B$16:$D$16)).

J’ai utilisé dans ma formule la fonction ET pour tester ces deux conditions.

Si les deux conditions sont respectées, Excel affichera le nom du fournisseur F1 qui se trouve dans la cellule B5, sinon il n’affichera rien.

Copiez la formule dans les deux autres cellules C20 et D20.

D’après les résultats obtenus, j’arrive à décider que le fournisseur F1 est celui que l’hôtel va choisir pour lui passer la commande.

Voilà donc, vous avez suivi comment réaliser un tableau de comparaisons des offres sous Excel, en vous basant sur un exemple d’un hôtel qui a voulu commander 150 chaises pour ses 150 chambres selon des critères précis, et vous avez vu comment faire pour arriver à choisir parmi trois fournisseurs celui le plus approprié. 

Bien évidemment, il existe d'autres exemples de choix de fournisseurs tel que le choix effectué à l'aide de critères pondérés.

Lire la suite »

Surligner les lignes contenant une ou des valeurs recherchées sous Excel

Comme vous le savez, lorsque vous utilisez la fonction RECHERCHEV, vous faites extraire les données d’un tableau qui correspondent à un terme recherché. Dans ce cours de la formation Excel, je vais vous montrer une astuce très importante qui va vous permettre, non d’extraire ces données, mais de repérer d’une façon visuelle la ou les lignes qui les contiennent.

Voici à quoi ressemble le résultat attendu :

Comme vous pouvez le remarquer, les lignes correspondant au terme recherché qui est le nom de la ville (ici « paris »), sont surlignées en bleu. Si je modifie par la suite la valeur recherchée, Excel appliquera cette mise en forme aux nouvelles lignes trouvées d’une façon dynamique.

Comment arriver donc à effectuer ce travail ? c’est ça ce que je vais vous expliquer à travers les lignes qui suivent. Vous allez découvrir en plus, deux autres exemples de cette technique de recherche.

Tout d’abord commencez par télécharger le fichier Excel sur lequel on va travailler en cliquant sur ce lien : télécharger l’exercice Excel

Rechercher par nom de ville :

• Dans la cellule I1 tapez « Paris » par exemple :
• Sélectionnez ensuite la plage de cellules A2:E19, c’est-à-dire toutes les cellules sauf les en-têtes.
• Cliquez sur Mise en forme conditionnelle, puis sur Nouvelle règle.

• Dans la fenêtre qui apparaît, sélectionnez le dernier type de règle : Utiliser une formule pour déterminer quelles cellules le format sera appliqué.
• Cliquez dans la zone d’insertion de formule, puis sélectionnez la cellule E2 correspondant au premier nom de ville.

• Vous remarquez qu’Excel a ajouté automatiquement les signes dollars à la référence de cette cellule. Tapez alors la touche F4 pour ne laisser qu’un seul signe devant la lettre E. l’objectif est donc de permettre à Excel de passer en revue tous les noms des villes de la colonne Ville.
• Après ça, tapez = puis sélectionnez la cellule contenant le terme recherché : I1, qui doit rester figée. ($I$1)

• Cliquez ensuite sur Format et choisissez une couleur de remplissage.

• Validez votre choix puis cliquez sur le bouton OK pour exécuter cette règle de mise en forme.
• Saisissez un autre nom de ville recherché puis validez.

Vous remarquez alors que la mise en évidence des lignes trouvées s’effectue instantanément.

Suivez l'explication en vidéo de cette procédure :

Télécharger le fichier Excel

Rechercher par ID

Répétez les mêmes étapes vues précédemment, mais au lieu de sélectionner la cellule E2, choisissez la cellule A2 correspondant au premier ID dans le tableau.

Choisissez également une autre couleur de remplissage.

Lorsque vous avez terminé, saisissez l’ ID à rechercher puis tapez Entrée.

Rechercher par tranche d’âge

Dans cet exemple, je veux qu’Excel surligne les lignes contenant les données correspondant aux personnes âgées entre 31 et 40 inclus.

Dans I1 tapez 31 et dans J1 tapez 40

Créez une nouvelle règle de mise en forme en suivant les mêmes étapes décrites en haut puis, et dans la zone d’insertion de formule tapez la formule suivante :

=ET($D2>=$I$1;$D2<=$J$1)

D2 correspond à la première cellule de la colonne Âge.

Appliquez une couleur de remplissage différente aux autres couleurs déjà sélectionnées dans les deux derniers exemples.

Validez puis jouissez du résultat obtenu.

Modifiez en cas de besoin l’intervalle d’âge, et remarquez le dynamisme et l’instantanéité de cette technique de recherche.

J'ai aussi expliquée cette démarche dans cette vidéo :

Après avoir appliqué ces trois règles de mises en forme, vous pouvez alors effectuer votre recherche selon le terme souhaité, Excel la traitera intelligemment et vous renverra le résultat que vous attendiez.

Lire la suite »

Comment avoir une liste déroulante dynamique de tous les vendredis de l'année spécifiée dans une autre liste déroulante ?

Un des visiteurs de mon blog Formation Excel a posté ce commentaire :« Je n'arrive pas à trouver la formule qui me permettra d'avoir une liste déroulante de tous les vendredis de l'année. A savoir que l'année concernée est choisie par une autre liste déroulante. »

Son message est clair, il a deux listes déroulantes, et il veut que lorsqu'il sélectionne une année dans la première liste, la seconde liste sera remplie de tous les vendredis correspondant à cette année.

Cet exercice ressemble à celui que j’ai traité dans un article précédent nommé : Comment créer des listes déroulantes dépendantes ou en cascade avec Excel ? (vous pouvez y jeter un coup d'œil si vous le désiriez) à une différence que dans l’exercice présent, les données que va contenir la liste déroulante dépendante, doivent être extraites d’un tableau ou plage de cellules à l’aide d’une formule de recherche.

Voici donc une capture du résultat estimé :

Comment procéder pour résoudre cet exercice ?

Pour vous donner une réponse directe :

• Nous allons dans un premier temps nous servir de la fonction INDEX pour extraire « tous les vendredis » à partir d’une colonne contenant tous les jours de l’année.
• Puis nous allons utiliser la fonction DECALER pour remplir la liste déroulante des résultats trouvés.

Soyez patient et suivez avec moi la procédure en dessous pour pouvoir répondre à la requête de notre ami !

Créez la liste déroulante des années

• Dans C1 tapez : Sélectionnez une année.
• Puis sélectionnez la cellule D1 et créez une liste déroulante contenant les années de 2019 à 2026 par exemple.

Créez une colonne contenant tous les jours de l’année

• Dans la cellule A1 tapez la formule suivante pour afficher le premier jour de l’année en fonction de l’année affichée dans D1 :

=DATE($D$1;1;1)

• Dans la cellule A2, insérez cette formule =A1+1 pour incrémenter la première date d’un jour puis cliquez sur la poignée de recopie et étirez vers le bas jusqu’à la cellule A365.
• Dans la cellule A366, entrez la formule suivante :

=SI(A365=DATE($D$1;12;30);A365+1;"")

A366 va afficher le dernier jour de l’année si elle est bissextile, si non la cellule n’affiche rien.

• Sélectionnez la plage A1:A366 et nommez-la par exemple : ListeJours

Extraire tous les vendredis à partir de la plage ListeJours en utilisant INDEX

En d’autres termes, nous effectuerons une recherche à l’aide d’INDEX pour renvoyer plusieurs résultats en fonction d’un seul critère qui est l’année sélectionnée.

Allons pas à pas pour arriver à atteindre ce but :

Identifier les cellules contenant tous les vendredis

• Sélectionnez G1 et saisissez la formule suivante : =JOURSEM(ListeJours;2)=5

En exécutant cette formule, Excel va vérifier si le chiffre renvoyé par la fonction JOURSEM est égal à 5 (désignant vendredi) ou non, et ceci en tenant en compte que le premier jour de la semaine est lundi, ce que nous l’avons indiqué à Excel en choisissant le chiffre 2 dans le deuxième argument de notre fonction JOURSEM.

• Comme vous le remarquez , Excel renvoie FAUX pour 01/01/2019.
• Copiez ensuite la formule vers le bas jusqu’à la cellule G366 et voyez ce que ça donne.

Note : ne vous dérangez pas si G366 affiche une erreur en cas d’une année régulière.

Depuis ce résultat, vous pouvez identifier les cellules qui contiennent tous les vendredis. Voici par exemple les premières montrées dans cette image :

Renvoyer les numéros de lignes des cellules affichant les dates trouvées :

Cette étape est très importante parce que nous avons besoin de connaitre les numéros de lignes des cellules qui contiennent tous les vendredis pour les référencer dans INDEX d’une façon à ce qu’elle puisse nous renvoyer tous les résultats trouvés.

Servez-vous de la fonction AGREGAT !

La fonction AGREGAT dans notre cas, va créer un ensemble de ces numéros de lignes en les faisant isoler des autres numéros des lignes qui ne répondent pas à notre condition.

Par exemple, les dates des vendredis trouvées pour 2019 se positionnent dans les lignes : 4,11,18,25,32…95,102,109 et ainsi de suite jusqu’à la ligne 361. C’est alors cette liste de chiffres que nous voulons les introduire dans INDEX pour renvoyer tous les vendredis de 2019.

Afficher les numéros de lignes des vendredis :

• Modifiez la formule qui existe dans G1 en tapant ceci :

=(JOURSEM(ListeJours;2)=5)/(JOURSEM(ListeJours;2)=5)

• Puis copiez-la vers le bas :

A ce stade, Excel effectuera les divisions FAUX/FAUX (0/0 ce qui renvoie l’erreurDIV#0)  et VRAI/VRAI (1/1). Les résultats renvoyés seront exploités dans l’étape suivante :

• Modifiez encore cette dernière formule dans G1, en la multipliant par LIGNE(A1) :

=((JOURSEM(ListeJours;2)=5)/(JOURSEM(ListeJours;2)=5))*LIGNE(A1)

• Attention aux parenthèses !
• Copiez la formule vers le bas
• Voilà, nos numéros de lignes émergent !

Utiliser AGREGAT

Pour assembler ces numéros de lignes comme je l’ai mentionné avant, nous allons utiliser la fonction PETITE.VALEUR qui se trouve parmi les fonctions que regroupe la fonction AGREGAT. La fonction PETIITE.VALEUR renvoie le ou les plus petits nombres dans une plage de cellules selon un paramètre spécifié.

L’utilité d’utiliser AGREGAT est que PETITE.VALEUR sera effectuée sur les valeurs numériques obtenue en ignorant ces erreurs DIV#0.

• Tapez la formule suivante dans H1 :

=AGREGAT(15;6;$G$1:$G$366;1)

• 15 : spécifie la fonction PETITE.VALEUR.
• 6 : est le numéro affecté à l’option permettant d’ignorer les valeurs d’erreur.
• $G$1:$G$366 : est la plage contenant les numéros de lignes concernés.
• 1 : est le paramètre qui désigne le rang du numéro à renvoyer. 

Excel va renvoyer donc la première petite valeur qui est 4.

Et avec une petite amélioration, nous pourrons obtenir une liste de tous les numéros de lignes.

Si nous comptons le nombre des numéros de lignes qu’affiche la plage $G$1:$G$366 ça peut varier entre 52 et 53 selon l’année choisie. Etant donnée, nous allons entrer la formule suivante à la place de 1 :

LIGNES($A$1:A1)

Cette formule permet d’incrémenter le numéro de ligne lorsqu’elle est copiée vers le bas, regardez l’exemple suivant :

Alors quand elle est insérée dans AGREGAT, elle nous donnera le résultat suivant :

• Après avoir modifié la formule dans H1, étirez vers le bas jusqu’à ce que vous obteniez une valeur d’erreur (#NOMBRE):

Voilà donc notre liste de tous les numéros de lignes dont nous avions besoin pour les utiliser dans INDEX est obtenue.

Remarque : il y a des années comme 2021 qui compte 53 vendredis, alors lorsque vous la sélectionnez, vous verrez que la dernière cellule H53 affiche le dernier numéro de ligne au lieu de la valeur d’erreur.

Utiliser la fonction INDEX

• Modifiez la formule dans H1 en y ajoutant INDEX :

=INDEX(ListeJours;AGREGAT(15;6;$G$1:$G$366;LIGNES($A$1:A1)))

INDEX va chercher dans la plage ListeJours la date correspondant au premier numéro renvoyé par AGREGAT qui est 4.

Alors, Excel affiche dans H1 : 04/01/2019. C'est la date du premier vendredi qui correspond à la 4^ème ligne.

Note : Appliquez le format Date à la cellule H1, si cette dernière n’affiche pas la date correctement.

• Copiez la formule vers le bas jusqu’à la cellule H53
• Tout fonctionne bien alors !

• Sélectionnez une autre année par exemple 2021 et voyez le résultat affiché.

La formule de recherche améliorée :

Nous ferons mieux si nous intégrons la formule utilisée dans G1:G366  directement dans notre formule de recherche au lieu de demander à Excel d’aller chercher à chaque fois les numéros de lignes dans la plage G1:G366. Voici ce que vous allez faire :

• Copiez la formule contenue dans la cellule G1 sans le signe = et collez-la à la place de  $G$1:$G$366 référencée dans AGREGAT.
• Modifiez ensuite LIGNE (A1) par LIGNE(ListeJours).
• Votre formule ressemblera à ceci :

=INDEX(ListeJours;AGREGAT(15;6;((JOURSEM(ListeJours;2)=5)/(JOURSEM(ListeJours;2)=5))*LIGNE(ListeJours);LIGNES($A$1:A1)))

• Copiez-la vers le bas.

Si vous êtes satisfait de ce résultat, supprimez le contenu de la colonne G.

Créez et remplissez la liste déroulante dépendante :

• Sélectionnez par exemple : C3 et tapez : Liste de tous les vendredis

Et pour créer et remplir finalement la liste déroulante des dates de tous les vendredis trouvés, nous allons utiliser la fonction DECALER :

• Nommez tout d’abord la plage H1:H53 : ListeVendredis
• Sélectionnez la cellule D3 et cliquez sur Validation des données puis choisissez Liste sous Autoriser
• Entrez la formule suivante dans la zone Source:

=DECALER($H$1;0;0;NB(ListeVendredis))

Excel renvoie donc les valeurs contenues dans la plage H1:H53 en fonction du nombre de résultats trouvés 52 ou 53.

• Faites un test pour vérifier si tout fonctionne comme il le faut.

Félicitations ! vous avez réussi à créer une liste déroulante dépendante affichant tous les vendredis en fonction de l’année sélectionnée dans l’autre liste déroulante.

Lire la suite »

Comment créer des listes déroulantes dépendantes ou en cascade avec Excel ?

Dans ce cours de la formation Excel, vous allez apprendre à créer une liste déroulante qui dépend d’une seconde liste déroulante et ceci sans macros, sans VBA et sans insérer de contrôle ActiveX ou de formulaire.

Une liste déroulante dépendante (ou en cascade comme préfèrent quelques utilisateurs de l’appeler) est une liste contrôlée par une autre liste déroulante, c’est-à-dire que les valeurs que va contenir une liste déroulante dépendent de la valeur (mère) sélectionnée dans l’autre liste.

Voici un exemple qui illustre les choses :

Comme vous le voyez, lorsque je sélectionne Agrumes dans la liste 1, la liste 2 se met à jour pour contenir les noms des fruits qui se trouvent sous cette catégorie, et la même chose se dit aussi pour les autres valeurs.

Alors pour obtenir ce résultat, suivez avec moi les démarches suivantes :

Comment créer des listes dépendantes ?

• Commencez tout d’abord par créer ce tableau illustré dans cette image :

Note : veuillez remarquer que les mots composant les noms des trois derniers entêtes sont liés par des Underscores au lieu de taper des espaces entre eux. (Lisez jusqu’à la fin pour comprendre pourquoi).

• Nommez ensuite chaque plage contenant les noms des fruits dans chaque colonne du même nom utilisé dans l’entête comme suit :
• Pour la colonne Agrumes :
• Sélectionnez la plage de cellules A2:A6 puis tapez le nom Agrumes dans la zone Nom et validez par Entrée.

• Pour la colonne Fruits_à_pépins :
• Sélectionnez la plage B2:B4 et donnez-lui le nom Fruits_à_pépins comme vous l’avez fait avec Agrumes, ou bien cliquez ; sous l’onglet Formules ; sur Définir un nom et tapez le nom de cette plage puis validez.

• Suivez les mêmes étapes pour les deux dernières colonnes Fruits_à_noyaux et Fruits_exotiques_et_tropicaux

Remarque : Vous pourriez copier les noms des entêtes au lieu de les saisir encore une fois.

Attention !

Les noms des plages de cellules ne doivent contenir que des lettres, des chiffres ou le caractère Underscore uniquement et ne doivent pas commencer par un chiffre. C’est pour cela que vous avez remarqué que j’ai utilisé des underscores au lieu des espaces.

Remplir la première liste déroulante :

• Sélectionnez la cellule qui va contenir la liste des types des fruits qui sont les noms des entêtes des colonnes de notre tableau. Dans mon cas j’ai choisi la cellule D12.
• Sélectionnez l’onglet Données puis cliquez sur Validation des données.
• Dans la boite de dialogue qui s’affiche sélectionnez Liste sous Autoriser.
• Cliquez ensuite dans la zone Source et sélectionnez la ligne des entêtes : A1:D1.
• Cliquez sur OK pour fermer la boite de dialogue.

• Voilà maintenant la première liste est créée.

Note : Vous pourriez savoir plus sur l’utilisation de Validation des données en visitant ce lien : Validation des données

Remplir la liste déroulante dépendante :

Pour remplir cette liste déroulante dépendant de la première liste, nous allons nous servir ;en plus de l’outil Validation de données ; de la fonction INDIRECT.

• Choisissez donc la cellule qui va contenir cette liste, dans notre exemple j’ai sélectionné D15.
• Cliquez sur Validation des données puis choisissez Liste et dans la zone Source tapez =INDIRECT( et sélectionnez la cellule D12 contenant la première liste puis fermez la parenthèse.
• La formule obtenue est donc =INDIRECT($D$12)
• Cliquez sur OK enfin.

Vous venez donc de terminer votre travail, et voici donc vos deux listes qui sont créées avec succès :

Erreur pouvant survenir !

Si INDIRECT ne contient pas la bonne référence de la cellule contenant la première liste déroulante ou si vous n’avez pas défini pour les plages des valeurs des noms identiques aux noms des entêtes des colonnes et qui respectent la règle de nomination des cellules, vous obtiendrez ce message d’erreur :

Lire la suite »