Formule de la moyenne pondérée

L’article présent de la Formation Excel vous explique comment créer une formule pour calculer la moyenne pondérée en vous servant de la fonction SOMMEPROD. Vous allez voir aussi comment faire pour que votre formule créée calcule automatiquement une moyenne pondérée lorsque vous insérez de nouvelles valeurs ou vous supprimez quelques-unes.
Formule moyenne pondérée


Une moyenne arithmétique simple est différente d’une moyenne pondérée. Dans l’article précédent (Calculer la moyenne des données filtrées ou non-filtrées en utilisant la fonction MOYENNE) j'ai montré comment calculer une moyenne arithmétique en utilisant la fonction Moyenne. Et pour calculer une moyenne pondérée, Excel ne fournit aucune fonction spécifique jusqu’à la publication de cet article. Cependant vous pouvez calculer cette moyenne en utilisant une fonctionne très importante qu’on appelle SOMMEPROD.

La moyenne pondérée

Une moyenne pondérée est une moyenne que l’on obtient en multipliant chaque valeur à son effectif appelé aussi poids, puis on additionne tous les produits obtenus, et enfin on divise la somme obtenue par le total des poids.

Dans l’exemple suivant, un étudiant a eu les notes suivantes pour les matières : Maths, physique et anglais où chaque matière possède son propre coefficient :

Tableau notes par matières


  • Pour calculer la moyenne pondérée de cet étudiant, on écrit :

(15x6)+(13x5)+(17x3)/6+5+3
  • Ce qui donne 206/14
  • La moyenne donc est 14,71

Si vous voulez faire ce calcul dans Excel, vous pouvez procéder ainsi :
  • Sélectionnez par exemple C5 dans le tableau suivant et tapez la formule suivante :

=((B2*C2)+(B3*C3)+(B4*C4))/(C2+C3+C4)
  • Et vous allez obtenir alors :  14,71
Formule simple moyenne pondérée



Cette formule sera très gênante surtout si votre tableau contient de multiples lignes. Alors et pour réduire ce travail, utilisez les deux fonctions SOMMEPROD et SOMME.

Présentation de la fonction SOMMEPROD

La fonction SOMMEPROD (Somme des Produits) permet de calculer la somme des produits des valeurs par leurs poids. C’est-à-dire que le travail que vous avez fait de calculer le produit de chaque note par son coefficient puis de calculer le total de ces produits, vous pouvez le faire aisément avec SOMMEPROD.

La syntaxe de la fonction SOMMEPROD

SOMMEPROD(matrice1, [matrice2], [matrice3], ...)

  • Vous allez donc taper à la place de l’argument matrice1 la référence de la plage de cellules B2:B4 qui contient les notes, et à la place de l’argument matrice2 tapez la référence de la plage de cellules C2:C4
  • Votre fonction sera écrite de cette façon : =SOMMEPROD(B2:B4;C2:C4)
Utiliser SOMMEPROD

  • Ce qui donne 206
  • Il vous reste enfin de diviser ce total par la somme des coefficients, c'est à dire : SOMME(C2:C4)
  • Alors pour calculer la moyenne pondérée, la  formule sera :

=SOMMEPROD(B2:B4;C2:C4)/SOMME(C2:C4)

Formule de la moyenne pondérée

  • Et c’est le même résultat obtenu précédemment : 14,71

Les matrices doivent avoir les mêmes dimensions :

Oui, effectivement, les matrices de la fonction SOMMEPROD doivent avoir le même nombre de lignes et de colonnes, si non votre formule renverra une erreur de type VALEUR. (pour plus de détails sur cette erreur consultez l’article suivant : Les erreurs dans Excel)

Dans l'exemple vu en haut, la matrice B2:B4 se compose d’une colonne et de trois lignes et c'est le même nombre de colonnes et de lignes pour la matrice C2:C4.

Regardez maintenant l’exemple suivant :

matrices de sommeprod


  • Les deux matrices contiennent chacune deux colonnes et trois lignes.
  • Alors, pour trouver la somme des produits des valeurs de la première matrice par celles de la deuxième matrice, suivez la procédure illustrée dans cette image animée :
Introduire des matrices dans SOMMEPROD

  • Le travail effectué par cette fonction suit l’ordre suivant :

(A1*D1)+(A2*D2)+(A3*D3)+(B1*E1)+(B2*E2)+(B3*E3)

Note : Vous pouvez utiliser jusqu’à 255 matrices dans la fonction SOMMEPROD

Calculer automatiquement la moyenne pondérée lors d’une insertion ou suppression de valeurs :

Dans cet exemple, vous allez voir comment calculer automatiquement le prix de vente moyen lorsque de nouveaux produits se sont ajoutés au stock mais qui se sont achetés à des prix différents.
  • Dans la cellule B7, tapez la formule pour calculer la moyenne pondérée comme suit :

=SOMMEPROD(A2:A6;B2:B6)/SOMME(A2:A6)

Exemple 2 de formule pour calculer moyenne pondérée

  • Faites maintenant de petites modifications, en imbriquant la fonction DECALER :
  • Remplacez la cellule A6 dans SOMMEPROD et SOMME par DECALER(A7;-1;0), et la cellule B6 par DECALER(B7;-1;0)
Fonction Decaler imbriquée dans SOMMEPROD

  • Insérez maintenant une nouvelle ligne juste en dessus de la cellule B7 qui contient votre formule, puis tapez les nouvelles valeurs : Quantité et Prix de vente.
Calcul automatique de moyenne pondérée lors d'insertion de nouvelles valeurs

  • Remarquez donc que la moyenne pondérée s’est calculée automatiquement.
  • Essayez cette fois de supprimer une ligne de ce tableau et remarquez aussi que votre formule moyenne pondérée s’effectue aussi automatiquement.
Calcul automatique de moyenne pondérée lors de suppression de valeurs


Différence entre MAX et MAXA, MIN et MINA

Dans cet article de la formation Excel, vous allez découvrir quelle différence existe entre les fonctions MAX et MAXA, et aussi entre les fonctions MIN et MINA dans Excel.
Différence entre MAX et MAXA MIN et MINA


Vous avez remarqué sans doute que lorsque vous voulez insérer la fonction MAX, vous voyez afficher une autre fonction MAXA. Quelle est donc la différence entre les deux ?

Syntaxe de la fonction MAXA

La syntaxe de la fonction MAXA est:  MAXA(valeur1,[valeur2],...)
L'argument valeur1 est obligatoire, quant aux autres arguments: valeur2, valeur3... ils sont facultatifs.

Cette fonction permet de trouver la valeur la plus grande dans une plage de cellules contenant des valeurs numériques, logiques ou textes. Tandis que la fonction MAX ignore les deux dernières valeurs: logiques et textes.


Regardez l’exemple suivant :

Utilisation de la fonction MAXA


La plage de cellules A2:A7, et comme vous le remarquez, contient trois types de données: 

  • Numériques: 0; 0,125; 0,65; et 0,13.
  • Texte: Bureau
  • Logique: VRAI
Ce que je veux donc, c'est afficher la valeur la plus grande parmi ces données.

Si j'utilise la fonction MAX, Excel affiche 0,65 parce que la fonction MAX ne prend en compte que les valeurs de type numériques et ignore les autres de types logique (Vrai ou Faux) et texte (Bureau).

Alors que la fonction MAXA que j'ai utilisée dans cet exemple, affiche la valeur 1 correspondant à VRAI , parce qu’elle prend en compte toutes les types de données: numériques, logiques et textes.

Dans le cas des valeurs logiques, MAXA donne la valeur 1 pour VRAI et la valeur 0 pour FAUX , et pour une valeur de type texte, elle a la valeur 0.

Les fonctions MIN et MINA

La même chose aussi se dit des fonctions MIN et MINA.
Regardez l’exemple suivant :

Utilisation de la fonction MINA


La fonction MINA renvoie donc 0 dans cet exemple, car la valeur Bureau est de type texte et c’est elle qui est la plus petite dans la plage référencée.

Et si j'utilise la fonction MIN, elle renvoie bien sûr la valeur numérique: 0,125.

MAX et MIN conditionnelles

Dans la leçon précédente utilisation de MAX et MIN, nous avons montré une procédure pour trouver la valeur maximale ou minimale selon un critère de filtrage. Aujourd’hui nous allons proposer d’autres méthodes pour rechercher le Max et le Min des valeurs dans une plage de cellules en répondant à certaines conditions contenues dans les autres colonnes de cette plage.

Max et Min conditionnelles

Utiliser une formule matricielle en imbriquant SI dans MAX ou MIN

Avec un seul critère

Dans l’exemple suivant, nous voulons trouver le montant le plus élevé et le plus bas pour la région de l’Italie.
  • Dans la première cellule qui va afficher le montant le plus élevé, tapez =MAX(SI(B2:B19=B4;D2:D19))
Utiliser Max et Si pour afficher le max conditionnel

  • Ici donc, nous avons imbriqué la fonction SI dans la fonction MAX.
  • Excel doit alors chercher dans la plage de cellules Région: B2:B19, toutes les cellules contenant Italie, puis il va renvoyer le montant le plus élevé lié à cette région et ceci à partir de la plage de cellules Montant D2:D19.

Note : les deux plages de cellules doivent avoir le même nombre de lignes pour qu’Excel renvoie le résultat demandé.
  • Tapez Entrée pour valider la formule.
  • Vous remarquez que la formule renvoie une erreur #Valeur.
  • Pour afficher donc le bon résultat, vous devez tapez Ctrl+Shift+Entrée parce que ce type de formules est considéré comme une formule matricielle, et remarquez les accolades qui se sont ajoutées dans la formule.
Formule matricielle Max et Si imbriquée

  • Excel affiche donc le montant le plus élevé dans la région de l’Italie.

Note : une formule matricielle permet d’effectuer des calculs impossibles à réaliser.

Procédez de la même manière en utilisant cette fois la fonction MIN pour trouver le montant le plus bas.

Formule matricielle Min et Si imbriquée

Avec plusieurs critères

Reprenons le même exemple précédent, et essayons maintenant de trouver la valeur maximale et minimale dans les deux régions Allemagne et Belgique.
  • Sélectionnez la cellule qui va afficher la valeur minimale puis écrivez : =MIN(SI(B2:B19=B3;D2:D19);SI(B2:B19=B9;D2:D19))
Deux conditions pour trouver le Min des valeurs

  • Vous remarquez que nous avons utilisé deux critères ici: la première fonction SI va chercher les montants correspondant à l’Allemagne : SI(B2:B19=B3;D2:D19)
  • Puis la deuxième fonction SI va chercher les montants correspondant à la Belgique : SI(B2:B19=B9;D2:D19)
  • Ensuite, Excel exécute la fonction MIN pour renvoyer le montant le plus bas dans ces deux résultats trouvés.
  • Composez encore Ctrl+Shift+Entrée pour valider cette nouvelle formule matricielle.
Trouver le min selon deux critères dans la même colonne

  • Vous pouvez également chercher le Max et le MIN selon deux critères appartenant à deux colonnes  différentes.
  • Par exemple vous pouvez chercher le montant le plus élevé du produit Céréales dans la région Allemagne.
trouver le Max selon deux critères dans deux colonnes


  • Voici le résultat:
Résutat Max avec deux critères de recherche


Dans Excel 2016, les choses se sont simplifiées avec l’arrivée des fonctions MAX.SI et MIN.SI

MAX.SI et MIN.SI ou MAX.SI.ENS et MIN.SI.ENS sont deux fonctions qui se sont apparues avec la venue de la version Excel 2016. (Elles sont 6 en total, vous les trouverez dans l'ebook gratuit Fonctions Excel 2016).
Ces deux fonctions vont faire le même travail que vous avez vu précédemment, mais d’une façon plus simple.
Vous devez donc posséder la version Excel 2016 ou bien vous connecter à Office365 et travailler sur Excel Online, ou même utiliser l’application Excel sur Android.
  • Voici la syntaxe de la fonction MAX.SI.ENS (ou MAX.SI)
MAX.SI.ENS(plage_max; plage_critère1; critère1; [plage_critère2; critère2]; ...)
  • plage_max : cet argument doit contenir la référence de la plage de cellules des valeurs dont nous voulons trouver la valeur maximale. Dans notre cas c’est la colonne Montant D2:D19.
  • plage_critère1 : nous devons référencer la plage de cellules où se trouve notre premier critère. C’est la colonne Région B2:B19 exactement.
  • critère1 : c’est la référence de la cellule ou une valeur qui va permettre de définir la valeur maximale recherchée. Et comme nous l’avons vu en haut, nous allons choisir la région de l’Italie et sélectionner donc B4.

Note : Vous pouvez aussi taper « Italie » tout simplement entre guillemets.

Avec un seul critère

  • Alors puisque nous allons travailler sur un seul critère, notre formule sera la suivante :
=MAX.SI.ENS(D2:D19;B2:B19;B4)

Insertion de MAX.SI.ENS

  • Tapez Entrée pour valider. Vous n’avez pas besoin donc de composer Ctrl+Shift+Entrée !!
  • Et voici le résultat.
Résultat d'utilisation de MAX.SI



Avec plusieurs critères

Si vous voulez utiliser plusieurs critères, la fonction MAX.SI.ENS exige que vous définissiez des critères appartenant à des colonnes différentes. Ce qui n’est pas le cas dans notre exemple en haut (MAX + SI).
Par exemple si vous avez inséré la fonction MAX.SI.ENS de cette façon :
=MAX.SI.ENS(D2:D19;B2:B19;B4;B2:B19;B2)
Excel renvoie 0 Euros, car vous avez utilisé deux critères de la même colonne.

Impossible d'executer MAX.SI.ENS avec deux critèes sur colonne


Comment les choses fonctionnent ?

Excel exécute la fonction de gauche à droite et mémorise en premier lieu les valeurs dont on veut trouver la valeur maximale, ici les montants de la colonne Montant .
Puis il sélectionne celles qui correspondent au critère défini, c’est-à-dire tous les montants de la région Italie dans notre cas :

Montants de la région Italie


Ensuite, Excel cherche les montants correspondant au critère Allemagne dans la dernière plage trouvée (regardez l’image précédente), ce qui est impossible.
Alors quand il exécute la fonction MAX.SI.ENS, il affiche 0.
Pour vous aider encore à bien comprendre cette dernière étape, Modifiez B2 par « Italie » ou une référence de cellule qui contient Italie et exécutez de nouveau la formule :

Répétition du même critère dans MAX.SI


Vous remarquez donc qu’excel affiche le bon résultat.
En réalité c’est une répétition des arguments pas de plus!

La bonne utilisation de MAX.SI.ENS en incluant plusieurs critères

  • Saisissez la formule suivante =MAX.SI.ENS(D2:D19;B2:B19;B4 ;
  • Sélectionnez maintenant la deuxième plage de critère, par exemple la colonne Produit C2:C19.
  • Tapez point-virgule et sélectionnez Produits laitiers dans la cellule C15 et qui est l’une des valeurs correspondant à la région Italie.
  • Fermez la parenthèse et validez.
La bonne utilisation de MAX.SI.ENS en incluant plusieurs critères

  • De la même façon donc, utilisez la fonction MIN.SI.ENS ou la fonction MIN.SI
MIN.SI.ENS incluant plusieurs critères




Comment utiliser les deux fonctions MAX et MIN pour toute une plage de cellules ou pour des cellules filtrées ?

Dans l’article présent de la Formation Excel, nous allons étudier les deux fonctions MAX et MIN en suivant des méthodes différentes d’insertion. En plus nous allons voir comment utiliser MAX et MIN avec les cellules filtrées.
Comment utiliser les deux fonctions MAX et MIN pour toute une plage de cellules ou pour des cellules filtrées


La fonction Max permet de connaître la valeur maximale dans une plage de données et la fonction Min permet de connaître la valeur minimale dans une plage de données. Elles sont toutes les deux des fonctions statistiques.

Utiliser la fonction MAX

Découvrez rapidement comment utiliser les deux fonctions MAX et MIN à travers cette vidéo :

Dans l’exemple suivant, vous allez utiliser la fonction MAX pour trouver le montant maximum dans la plage D2:D19.
  • Sélectionnez la cellule D20 puis tapez =MAX( et sélectionnez la plage de cellule D2 :D19.
Sélection de la plage de cellules à utiliser dans la fonction MAX

  • Fermez la parenthèse et validez par Entrée.
Insertion de la fonction MAX

  • Vous pouvez aussi cliquez sur MAX dans le menu Somme automatique soit dans le groupe Edition sous l’onglet Accueil, soit sous l’onglet Formules.
Menu Somme automatique et fonctions MAX et MIN

  • Excel affiche donc la valeur maximale.
Résultat de la fonction MAX


Utiliser la fonction MIN

De la même façon, vous pouvez trouver le montant minimum dans la plage de cellules D2 :D19.
  • Sélectionnez D20 et tapez =MIN( puis sélectionnez la plage de cellules D2:D19.
  • Fermez la parenthèse et tapez Entrée.
  • La valeur minimale est affichée.
Insertion de la fonction MIN

  • Vous pouvez aussi insérer la fonction MIN à partir du menu Somme automatique.

Trouvez rapidement la valeur maximale et minimale

Sélectionnez la plage de cellules puis regardez en bas, dans la barre d’état, vous voyez qu'Excel affiche la valeur Max et Min.

Afficher MAX et MIN dans la barre d'état


Les nouvelles valeurs insérées ou supprimées sont prises en compte par les fonction MAX et MIN

Reprenons l’exemple précédent.
  • Insérez maintenant une ligne avant la cellule contenant la fonction MAX ou MIN.
  • Dans notre exemple, la fonction MAX (MIN) est décalée vers la cellule D21.
  • Saisissez un nouveau montant et remarquez que le résultat est mis à jour automatiquement.
Mise à jour de MAX et MIN lors d'une insertion de ligne nouvelle

  • Essayez à présent de supprimer une ligne de votre tableau et regardez la valeur que renvoie la fonction MAX ou MIN.
Mise à jour de MAX et MIN lors de suppression des lignes



Les fonctions MAX et MIN sont disponibles aussi dans la ligne des totaux

Lorsque vous appliquez un style de tableau à votre tableau de données et vous insérez une ligne des totaux, vous pouvez choisir la fonction que vous aimez utiliser MAX ou MIN.
Regardez l’exemple suivant :

Utiliser Outils de tableau pour trouver le MAX et le MIN


Trouvez la valeur maximale ou minimale dans une plage de cellules filtrées


La bonne solution et la plus simple est de passer par l’utilisation de la fonction SOUS.TOTAL (déjà vue lors de l'utilisation de la fonction SOMME).
  • Sélectionnez donc la cellule qui va contenir la fonction SOUS.TOTAL ; dans notre cas c’est la cellule D20
  • Tapez = SOUS.TOTAL(4 ;D2 :D19) puis validez par Entrée pour trouver la valeur maximale.
Insertion de MAX à partir de la fonction SOUS.TOTAL

  • Ou Tapez = SOUS.TOTAL(5 ;D2 :D19) puis validez par Entrée pour trouver la valeur minimale.
Insertion de MIN à partir de la fonction SOUS.TOTAL

  • Supposons maintenant que vous voulez connaître le montant le plus élevé dans la région de l’Allemagne.
  • Cliquez sur la cellule contenant le nom Allemagne avec le bouton droit de la souris, puis sélectionnez dans la liste qui s’affiche : Filtrer puis Filtrer par la valeur de la cellule sélectionnée.
Filtrer des données avec bouton droit de la souris

  • Excel affiche les données convenables et vous remarquez que la fonction MAX est mise à jour automatiquement.
Max des cellules filtrées


  • Procédez de la même manière pour la fonction MIN.
MIN des cellules filtrées


Note : vous avez remarqué sans doute que dans la liste des fonctions affichées vous avez deux fois le  nom de la fonction MAX et également deux fois le nom de la fonction MIN, et chacune d'elle est associée à un chiffre différent:
  • Pour la fonction MAX, elle est spécifiée par deux nombres 4 et 104.
  • Et pour la fonction MIN, ce sont 5 et 105.

Quand vous masquez des lignes manuellement de votre tableau, choisissez 104 ou 105 pour n’afficher que les valeurs maximales ou minimales des cellules visibles et ignorer celles masquées.

Mais au contraire, si vous choisissez 4 ou 5, les deux fonctions vont renvoyer les valeurs maximales ou minimales de toute la plage de cellules sans ignorées les cellules masquées.

Suivez cet exemple dans cette illustration:

Mise à jour de MAX après avoir masqué manuellement des cellules


En cas du filtrage comme vous l’avez vu précédemment, les deux fonctions traiteront uniquement les valeurs des cellules visibles et ignorent les cellules masquées quelques soit votre choix(4 et 104 ou 5 et 105).

La bonne solution pour calculer un cumul sans erreur dans Excel

Aujourd'hui sur Formation Excel, vous allez découvrir 3 méthodes utilisées pour calculer des cumuls sous Excel, et vous allez voir la plus efficace parmi ces trois méthodes qui vous évitera d'avoir des erreurs dans vos cumuls. En plus, et à la fin de cet article, vous allez voir comment calculer des cumuls en pourcentage. 

La bonne solution pour calculer un cumul sans erreur dans Excel


Méthode 1: Ce qui est habituel!

Regardez l’exemple suivant, c’est la colonne Cumul qui va afficher les cumuls calculés.

Colonne cumul


La méthode la plus simple est la suivante :
  • Dans la cellule C2 tapez =B2. Pour afficher le premier cumul.
  • Puis dans la cellule C3 tapez =B3+C2 et validez. Le deuxième cumul additionne le premier cumul contenant dans la cellule C2 à la valeur de la deuxième cellule B3.
  • Copiez ensuite la formule précédente dans le reste des cellules de la colonne Cumul:
calcul simple d'un cumul



Mais le problème qui peut survenir c'est que lorsque vous supprimez une ligne de votre tableau, Excel va renvoyer une erreur de référence #REF. (Pour plus de détails sur cette erreur et les erreurs dans Excel consultez l’article Les erreurs dans Excel )

Erreur REF dans la formule de cumul


Comment résoudre donc ce problème ?

Méthode 2: Calculer le cumul à l'aide de la fonction SOMME

Le mieux donc est d’utiliser la fonction SOMME pour calculer vos cumuls, et voici comment procéder :
  • Sélectionnez la cellule C2 et tapez =SOMME(B2:B2), c’est-à-dire que vous faites la somme de la plage B2:B2, ce qui va vous afficher la valeur contenue dans B2.
Somme d'une même cellule


Note : quand vous tapez = SOMME (B2  et vous ajoutez les deux points : Excel insère automatiquement B2 !
  • Continuons...
  • Vous allez maintenant copier cette formule dans le reste de la colonne Cumul, mais avant de le faire, vous devez figer la première référence B2.
  • Fixez alors la première référence B2 en y ajoutant des dollars $B$2 ou cliquez sur elle et tapez la touche F4 , et laissez la deuxième B2 telle qu’elle est.
  • En effet, la copie de la formule va incrémenter les références relatives des cellules (B3,B4,B5...B12), et la référence $B$2 (référence absolue) restera la même. Regardez l'image suivante :
Calculer le cumul dans Excel avec la fonction SOMME



  • Cette méthode vous permet donc de calculer les sommes des plages B2:B3, B2:B4, B2:B5...B2:B12, et de les placer successivement dans les cellules C3,C4,C5...C12.
  • Essayez à présent de supprimer une ligne de votre tableau et remarquez que votre cumul s'effectue de nouveau automatiquement.

Or, il se peut qu’un autre problème survienne  encore ! C’est quand vous souhaiterez filtrer vos données !
Par exemple, je veux afficher le cumul des montants des ventes du 2ème trimestre, je sélectionne donc les 3 mois Avril,Mai et Juin, ce qui donne le résultat suivant :

Erreur de cumul des cellules filtrées


Excel ne calcule pas automatiquement les cumuls, n’est-ce pas ?!

Voici à mon avis la solution la plus efficace pour éviter ces erreurs de cumul:

Méthode 3: Calculer le cumul en utilisant la fonction SOUS.TOTAL

Vous vous êtes habitués maintenant avec l’utilisation de la fonction SOUS.TOTAL ! Oui, vous l’avez vue dans les deux derniers articles.
Alors abordons-la également ici :
  • Sélectionnez la cellule C2 et insérez la formule suivante : =SOUS.TOTAL(109;$B$2:B2)
Insertion de la fonction sous.total


Note : L’argument 109 spécifie la fonction SOMME et c’est plus avantageux que l’argument 9.
Cumul des cellules filtrées ou visibles

  • Ne trouvez-vous pas que c’est très efficace ! 
Si vous avez une autre solution n’hésitez pas à me la communiquer J

Vous arrivez maintenant à la fin de cet article, et vous allez voir deux exemples qui vont vous montrer comment calculer le cumul en pourcentage:

Calculer des cumuls en pourcentage ( Exemple 1)

C'est une opération très facile, puisque vous avez déjà calculé les cumuls.
  • Commencez par sélectionner la première cellule de la colonne %Cumul qui va afficher le cumul en pourcentage. Dans notre exemple c’est la cellule D2.
  • Tapez la formule suivante : =C2/$C$13
Calculer le cumul en pourcentage

  • C2 contient le premier cumul et C13 contient le total des cumuls. Notez ici que vous devez figer la cellule C13 parce que vous allez copier la formule.
  • Faites la copie donc de la formule dans les autres cellules.
  • Sélectionnez à présent la plage de cellules D2:D13 et dans le groupe Nombre sous l’onglet Accueil choisissez le format pourcentage.
Choisir le format pourcentage
  • Voici le résultat obtenu:
Résultat cumul en pourcentage




Calculer le cumul en pourcentage des cellules filtrées (  Exemple 2) 

Dans cet exemple, nous avons filtré notre tableau précédent en sélectionnant les mois du deuxième trimestre:
Remarquez alors que les formules se trouvant dans la colonne %Cumul se mettent à jour automatiquement pour prendre en compte les nouvelles valeurs visibles:
Par exemple: la cellule D5 contient, dans ce cas, la formule =C5/$C$7


Cumul en pourcentage des cellules filtrées